home *** CD-ROM | disk | FTP | other *** search
/ CU Amiga Super CD-ROM 25 / CU Amiga Magazine's Super CD-ROM 25 (1998)(EMAP Images)(GB)(Track 1 of 2)[!][issue 1998-08].iso / InitCD < prev    next >
AmigaDOS Script File  |  1998-06-28  |  6KB  |  201 lines
  1. .key arg
  2. .bra {
  3. .ket }
  4.  
  5. ; CUCD Init Script
  6. ;
  7. ; Set up assigns etc. both for users booting from the CD and from  HD
  8. ;
  9. ; Version 1.1 - Changed jpegtmp
  10. ;
  11. ; Version 1.2 - Added uninit option
  12. ;
  13. ; Version 1.3 - Added CHECK argument and link to Prefs editor
  14. ;
  15. ; Version 1.4 - Added section to copy CUCDfile and IDer.prefs to hard drive if not already present
  16. ;
  17. ; Version 1.5 - Got rid of calls to updatecopy and replaced them with version/if warn
  18. ;               Hopefully cured the problem of the CD icon not leaving Workbench after running UninitCD
  19.  
  20. Assign CUCD: :
  21.  
  22. ;;; Make some commands resident to speed up things on CD32s in particular
  23. Resident >NIL: CUCD:C/RequestChoice PURE
  24. Resident >NIL: CUCD:rexxc/rx PURE
  25. Resident >NIL: CUCD:C/Version PURE
  26. ;;;
  27. ;;; Exit if InitCD has been run, otherwise ask
  28. If {arg} EQ "CHECK"
  29.     If $CDInit EQ TRUE
  30.         Skip END
  31.     Else
  32.         set init `CUCD:C/RequestChoice "CU Amiga CD" "InitCD needs to be run first*NWould you like to run it now?" "Yes|No"`
  33.         If $init EQ 0
  34.             Skip END
  35.             EndIf
  36.         EndIf
  37.     EndIf
  38. ;;;
  39. ;;; Give option to run UninitCD
  40. If $CDInit EQ TRUE
  41.     If $CDBoot EQ TRUE          ; don't run UninitCD if booted from CD
  42.         CUCD:C/RequestChoice >NIL: "CU Amiga CD" "You do not need to run InitCD*Nwhen you have booted from the CD" "OK" 
  43.         Skip END
  44.         EndIf
  45.     set remass `CUCD:C/RequestChoice "InitCD" "You have already run InitCD once.*NDo you wish to remove the assigns and paths added before?" "Remove|Cancel"`
  46.     If $remass EQ 1
  47.         execute UnInitCD
  48.         EndIf
  49.     Skip END
  50.     EndIf
  51. ;;;
  52. ;;; Set some system assigns and paths
  53. Assign WWW:             CUCD:CUCD/WWW
  54. Assign tcpdldir:        CUCD:CUCD/WWW
  55. Assign CUCDNews:        CUCD:CUCD/Online/News
  56. Assign Twist:           CUCD:CUCD/Magazine/Issues
  57. Assign TwistIcon:       Twist:Icons
  58. ;;;
  59. ;;; Add MUI if no MUI installed.
  60. Assign MUI: EXISTS >NIL:
  61. IF WARN
  62.     Assign MUI:    CUCD:CDsupport/MUI
  63.     Assign Libs:   MUI:Libs ADD
  64.     Assign LOCALE: MUI:Locale ADD
  65.     Assign HELP: exists >NIL:
  66.     If NOT WARN
  67.         Dir >NIL: HELP:
  68.         EndIf
  69.     Assign HELP:   MUI:Docs ADD
  70.     EndIf
  71. ;;;
  72. ;;; Set assigns and paths for programs on this CD
  73. Execute CUCD:S/ThisCD
  74. ;;;
  75. ;;;BEGIN ClassAct
  76. CUCD:C/CAPrefs >NIL:
  77. ;;;END ClassAct
  78. ;;; Commands to be run only if booting from CD
  79. IF $CDBoot EQ TRUE
  80.     Run <NIL: >NIL: C:NewIcons
  81.     CUCD:C/DefIcons
  82.  
  83.     ; Run these only if booting from a real CD32
  84.     Version >NIL:
  85.     if $kickstart EQ "40.60"
  86.         ;C:CD2XSpeed
  87.         C:NoReset
  88.         EndIf
  89.  
  90.     ; Allow alternative screenmodes
  91.     if $CUCDscreen EQ "NTSC"
  92.         :Storage/Monitors/NTSC
  93.         :Prefs/ScreenMode from :Prefs/Presets/NTSC USE
  94.         :Prefs/Input from :Prefs/Presets/USkey USE
  95.         setenv VisageOpts MONITOR=NTSC
  96.         endif
  97.     if $CUCDscreen EQ "VGA"
  98.         :Storage/Monitors/DblPAL
  99.         :Prefs/ScreenMode from :Prefs/Presets/VGA USE
  100.         setenv VisageOpts MONITOR=DblPAL
  101.         endif
  102.     unsetenv CUCDscreen
  103. ;;;
  104. ;;; All this is only needed when not booting from the CD
  105. Else
  106.     ; Make sure LIBS: has up to date copy of asyncio.library, to fix problems with earlier InitCD
  107.     Version >NIL: LIBS:asyncio.library 39 2 file
  108.     If WARN
  109.         copy CUCD:Libs/asyncio.library LIBS: CLONE
  110.         EndIf
  111.  
  112.     ; add CD assigns and paths
  113.     Assign DEVS:    CUCD:Devs ADD
  114.     Assign Fonts:   CUCD:Fonts ADD
  115.     Assign Libs:    CUCD:Libs ADD
  116.     Assign L:       CUCD:L ADD
  117.     Assign S:       CUCD:S ADD
  118.     Assign LIBS:    CUCD:Classes ADD
  119.     Path CUCD:C CUCD:CDsupport CUCD:System CUCD:Utilities CUCD:S CUCD:Rexxc ADD
  120.  
  121.     ; Start arexx if not running
  122.     CUCD:rexxc/rx "address command" >NIL:
  123.     If WARN
  124.         CUCD:System/RexxMast >NIL:
  125.         EndIf
  126.     ; Make sure icon.mcc is available for CUCDprefs
  127.     Version >NIL: MUI:Libs/MUI/Icon.mcc 1 1
  128.     If WARN
  129.         Copy >NIL: CUCD:CDsupport/MUI/Libs/MUI/Icon.mcc MUI:Libs/MUI CLONE
  130.         EndIf
  131.  
  132.     ; Give option for setting CD preferences, make sure CUCDfile and IDer
  133.     ; are in basic command path, so it will run without InitCD
  134.     If NOT EXISTS C:CUCDfile
  135.         Copy >NIL: CUCD:C/CUCDfile C: CLONE
  136.         EndIf
  137.     Version >NIL: C:IDer 1 6
  138.     If WARN
  139.         Copy >NIL: CUCD:C/IDer C: CLONE
  140.         EndIf
  141.     ; ensure IDer.prefs are available
  142.     If NOT EXISTS ENV:IDer.prefs
  143.         If NOT EXISTS S:IDer.prefs
  144.             Version >NIL: version 39
  145.             If NOT WARN
  146.                 Copy >NIL: CUCD:S/IDer.prefs S:IDer.prefs
  147.                 set edit `RequestChoice "CU Amiga CD" "CUCD now has a preferences program to specify*N the tools used to view/hear different types of files.*NWould you like to run it now?" "Yes|No"`
  148.                 If $edit EQ 1
  149.                     cd CUCD:S
  150.                     :RexxC/MuiRexx CUCDPrefs.mrx port CDPREFS
  151.                 Else
  152.                     RequestChoice >NIL: "CU Amiga CD" "You can run CUCD preferences at any time.*NIt is in the Prefs drawer of the CD" "OK"
  153.                     EndIf
  154.             Else
  155.                 Copy >NIL: CUCD:S/IDer.prefs_OS2 ENV:IDer.prefs
  156.                 EndIf
  157.             EndIf
  158.         EndIf
  159.  
  160.     ; Make environment variables defined on CD available to system
  161.     Failat 21
  162.     Assign >NIL: ENV: CUCD:Prefs/Env-Archive ADD
  163.     ; For HappyENV users
  164.     If FAIL     
  165.         Assign >NIL: ENVARC: CUCD:Prefs/Env-Archive ADD
  166.         EndIf
  167.  
  168.     ;Start NewIcons if not already running
  169.     If $NoNewIcons NOT EQ TRUE
  170.         CUCD:C/isnirunning
  171.         If NOT WARN
  172.             Run <NIL: >NIL: CUCD:C/NewIcons
  173.             CUCD:C/DefIcons
  174.             EndIf
  175.         EndIf
  176.  
  177.     ; Update workbench paths unless running Directory Opus 5.11 or 5.5 in WBR mode
  178.     Version >NIL: C:LoadWB 43
  179.     If WARN
  180.        C:LoadWB NEWPATH
  181.     Else
  182.         Version >NIL: C:LoadWB 60
  183.         If NOT WARN
  184.             C:LoadWB NEWPATH
  185.             EndIf
  186.         EndIf
  187.  
  188.     RequestChoice >NIL: "InitCD" "InitCD has set up some assigns and paths to run software from the CD.*NIf you wish to remove the CD from the drive, run InitCD again,*Notherwise the icon will stay on your Workbench." " OK "
  189.     EndIf
  190. ;;;
  191. SetEnv CDInit TRUE
  192.  
  193. LAB END
  194.  
  195. ;;; Remove commands made resident earlier
  196. Resident >NIL: RequestChoice REMOVE
  197. Resident >NIL: rx REMOVE
  198. Resident >NIL: Version REMOVE
  199. ;;;
  200.  
  201.